scim-qtimm-0.9.4.ebuild

scim-qtimm-0.9.4.ebuild (text/plain), 2.05 KB, created by David Chang on 2007-06-06 19:24:38 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/scim-qtimm/scim-qtimm-0.9.4.ebuild,v 1.17 2007/05/31 20:32:35 armin76 Exp $

WANT_AUTOMAKE="1.9"
WANT_AUTOCONF="latest"

inherit kde-functions eutils autotools

DESCRIPTION="Qt immodules input method framework plugin for SCIM"
HOMEPAGE="http://scim.freedesktop.org/"
SRC_URI="mirror://sourceforge/scim/${P}.tar.bz2
	http://freedesktop.org/~scim/${PN}/${P}.tar.bz2
	mirror://gentoo/kde-admindir-3.5.3.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 hppa ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="debug"

RDEPEND=">=app-i18n/scim-1.4.2
	virtual/libintl
	$(qt_min_version 3.3.4)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/pkgconfig"

pkg_setup() {
	if ! built_with_use =x11-libs/qt-3* immqt-bc && ! built_with_use =x11-libs/qt-3* immqt; then
		die "You need to rebuild >=x11-libs/qt-3.3.4 with immqt-bc(recommended) or immqt USE flag enabled."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	rm -rf "${S}/admin"
	ln -sf "${WORKDIR}/admin" "${S}/admin"

	epatch "${FILESDIR}/${P}-qtimm-check.patch"
	
	if ! use debug; then
		epatch "${FILESDIR}/disable-debug.diff"
	fi
	
	epatch "${FILESDIR}/suse-bugzilla-116220-keyboard-layout.patch"


	# Fix for autoconf 2.60
	sed -i -e '/case $AUTO\(CONF\|HEADER\)_VERSION in/,+1 s/2\.5/2.[56]/g' \
		admin/cvs.sh

	export WANT_AUTOCONF WANT_AUTOMAKE
	emake -j1 -f admin/Makefile.common || die "reautotooling failed"
}

src_compile() {
	local myconf="--disable-debug"
	
	use debug && myconf="--enable-debug=full --enable-scim-debug"
	econf \
		${myconf} \
		--disable-static \
		--disable-dependency-tracking || die "econf failed"
	emake || die "make failed."		
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	dodoc AUTHORS ChangeLog README NEWS TODO
}

pkg_postinst() {
	elog
	elog "After you emerged ${PN}, use right click to switch immodules for Qt."
	elog "If you would like to use ${PN} as default instead of XIM, set"
	elog "	% export QT_IM_MODULE=scim"
	elog
}